1. @echo off

    rem 设置标题

    title windows 7 无线热点设置 author:星辰 2014-12-13

    rem 设置背景颜色

    color 1E

    :: 设置窗口大小

    mode con: cols=100 lines=50

    ::--------------------------定义主程序标签

    :main

    ::--------------------------清屏

    cls

    echo.

    echo.       /-------------------------------

    echo.       ‖     windows 7 无线热点设置    ‖

    echo.       -------------------------------/

    echo.

    echo.        ======author:星辰 2014-12-13======

    echo.

    echo.            1 - 显示无线热点状态

    echo.            2 - 打开无线热点

    echo.            3 - 关闭无线热点

    echo.            4 - 禁用无线热点

    echo.            5 - 启用无线热点

    echo.            6 - 更改无线热点参数(SSID/KEY)

    echo.            0 - 退出

    echo.-----------------------------------------------------------

    echo.          首次运行请执行6      

    echo.          直接回车可查看说明文档

    set input=

    :: ---------------------------set /p是提示用户输入选择项

    set /p input=请选择【输入序号,然后回车】:

    if /i '%input%'=='1' goto main1

    if /i '%input%'=='2' goto main2

    if /i '%input%'=='3' goto main3

    if /i '%input%'=='4' goto main4

    if /i '%input%'=='5' goto main5

    if /i '%input%'=='6' goto main6

    if /i '%input%'=='0' goto end

    ::----------------------------如果选择项不在范围之内则提示用户重新选择。

    cls

    echo /====================================帮助====================================

    echo.

    echo /==============首次运行本程序开wifi,运行完后需要设置网络共享。

    echo /==============设置方法如下:

    echo /==============在“网络连接”窗口中,右键单击已连接到Internet的网络连接(一般是“本地连接”),

    echo /==============选择“属性”→“共享”,勾上“允许其他······连接(N)”并选择刚才新建的虚拟连接。

    pause

    goto main

    ::----------------------------退出

    :end

    set ssid=

    set key=

    exit

    ::----------------------------查看系统当前无线热点状态

    :main1

    cls

    echo 系统当前无线热点状态

    netsh wlan show hostednetwork

    ::----------------------------换行显示

    echo.

    pause

    goto main

    ::----------------------------打开无线热点

    :main2

    cls

    echo 打开无线热点

    netsh wlan start hostednetwork

    echo.

    pause

    goto main1

    ::----------------------------关闭无线热点

    :main3

    cls

    echo 关闭无线热点

    netsh wlan stop hostednetwork

    echo.

    pause

    goto main1

    ::----------------------------禁用无线热点

    :main4

    cls

    echo 禁用无线热点

    netsh wlan set hostednetwork mode=disallow

    echo.

    pause

    goto main1

    ::----------------------------启用无线热点

    :main5

    cls

    echo 启用无线热点

    netsh wlan set hostednetwork mode=allow

    pause

    goto main2

    ::----------------------------更改无线热点参数(SSID/KEY)

    :main6

    cls

    echo 更改无线热点参数(SSID/KEY)

    netsh wlan stop hostednetwork

    set ssid=

    set /p ssid=请输入热点名称:

    set key=

    set /p key=请输入网络密码(8位以上):

    echo.

    netsh wlan set hostednetwork mode=allow ssid=%ssid% key=%key%

    pause

    goto main2

浏览 565 评论 0 赞 3 砸 0 标签: bat 系统
评论
还可以再输入500个字

请您注意

·自觉遵守:爱国、守法、自律、真实、文明的原则
·尊重网上道德,遵守《全国人大常委会关于维护互联网安全的决定》及中华人民共和国其他各项有关法律法规
·严禁发表危害国家安全,破坏民族团结、国家宗教政策和社会稳定,含侮辱、诽谤、教唆、淫秽等内容的作品
·承担一切因您的行为而直接或间接导致的民事或刑事法律责任
·您在NoteShare上发表的作品,NoteShare有权在网站内保留、转载、引用或者删除
·参与本评论即表明您已经阅读并接受上述条款